bat 批处理脚本 - 一键开启和关闭 Windows 系统代理

开启代理（将脚本中的 IP:PORT 换成代理服务器的地址和端口）：

@echo off 
echo 开始开启系统代理，请稍候...
echo=
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f >nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "IP:PORT" /f >nul 2>nul
echo 系统代理已开启，请按任意键关闭本窗口...
pause>nul

关闭代理：

@echo off 
echo 正在关闭系统代理，请稍候...
echo=
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f >nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f >nul 2>nul
echo 系统代理已关闭，请按任意键退出本窗口...
pause>nul

根据当前配置自动开启或关闭代理（将脚本中的 IP:PORT 换成代理服务器的地址和端口）：

@echo off
for /f "tokens=1,2,* " %%i in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable ^| find /i "ProxyEnable"') do (set /A ProxyEnableValue=%%k)

if %ProxyEnableValue% equ 0 (
    echo 系统代理目前处于关闭状态，正在开启代理，请稍候...
    echo=
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f >nul 2>nul
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "IP:PORT" /f >nul 2>nul
    echo 系统代理已开启，请按任意键关闭本窗口...
) else if %ProxyEnableValue% equ 1 (
    echo 系统代理目前处于开启状态，正在关闭代理，请稍候...
    echo=
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f >nul 2>nul
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f >nul 2>nul
    echo 系统代理已关闭，请按任意键退出本窗口...
)
pause>nul

为了更加方便开启/关闭代理，可以给它设置个快捷键！
首先将 bat 脚本文件发送一个快捷方式到桌面（也方便从桌面双击运行），右键【属性】-【快捷方式】-【快捷键】，给它设置一个你自己习惯的快捷键即可。如下图所示：

注意：
如果执行 bat 脚本时中文的部分产生乱码，是因为脚本不是 ANSI 编码，需要修改脚本的编码格式。可使用记事本打开脚本，点击菜单【文件】-【另存为】，选择 ANSI 编码进行保存。如下图所示：