如何将 compileJava 任务（11）和 compileKotlin 任务（1.8）jvm 目标兼容性设置为 build.gradle.kts 中的相同 Java 版本？

Question

构建.gradle.kts

 buildscript {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath ("com.android.tools.build:gradle:7.0.2")
        classpath ("org.jetbrains.kotlin:kotlin-gradle-plugin:1.5.30")
        classpath("gradle.plugin.com.github.spotbugs.snom:spotbugs-gradle-plugin:${Versions.spotbugsGradlePluginVersion}")
        classpath("se.bjurr.violations:violations-gradle-plugin:${Versions.violationsVersion}")

    }
}
//android {
//    compileOptions {
//        sourceCompatibility = JavaVersion.VERSION_11
//                targetCompatibility = JavaVersion.VERSION_11
//    }
//
//    kotlinOptions {
//        jvmTarget = JavaVersion.VERSION_11.toString()
//    }
//}
plugins {
    `maven-publish`
    `java-gradle-plugin`
    `kotlin-dsl`
    id ("io.gitlab.arturbosch.detekt") version ("1.18.1")
}
repositories {
    google()
    mavenCentral()
    gradlePluginPortal()
}

dependencies {
    compileOnly(gradleApi())
    testImplementation(gradleTestKit())
    testImplementation("junit:junit:${Versions.jUnitVersion}")
}
val generatedSources = tasks.register<GenerateVersionsFileTask>("generateSources")

错误：“compileJava”任务（当前目标为 11）和“compileKotlin”任务（当前目标为 1.8）jvm 目标兼容性应设置为相同的 Java 版本。

当我取消注释 android {} 错误时：脚本编译错误：

  Line 15: android {
           ^ Unresolved reference: android

感谢您的时间和努力:) Jitendra

原文由 jitendra kumar 发布，翻译遵循 CC BY-SA 4.0 许可协议

Answer 1

您可以为 java 设置 java 版本

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

或者：

 java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(11))
}

对于科特林：

 tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile>().configureEach {
    kotlinOptions {
        jvmTarget = "11"
    }
}

所有样本都在 gradle kotlin dsl 中。

原文由 Marian 发布，翻译遵循 CC BY-SA 4.0 许可协议