机器人框架下载文件

我使用机器人框架。

在我的 HTML 页面上，我有一个简单的按钮。当您单击它时，它会下载一个 PDF 文件。

如果文件已下载，我如何检查 Robot Framework？

原文由 Raphael 发布，翻译遵循 CC BY-SA 4.0 许可协议

阅读 268

该解决方案是非常特定于浏览器的。对于 Chrome，您可以告诉 Chrome 从哪里下载文件。选择新文件夹可让您监控下载状态。此外，由于您正在下载 PDF，因此有必要禁用 PDF 插件以防止显示 PDF 而不是下载。这是使用简单页面和 PDF 文件在我的机器上运行的测试。

 *** Settings ***
Test Teardown     Close All Browsers
Library           Selenium2Library
Library           OperatingSystem

*** Test Cases ***
Download PDF
    # create unique folder
    ${now}    Get Time    epoch
    ${download directory}    Join Path    ${OUTPUT DIR}    downloads_${now}
    Create Directory    ${download directory}
    ${chrome options}=    Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    # list of plugins to disable. disabling PDF Viewer is necessary so that PDFs are saved rather than displayed
    ${disabled}    Create List    Chrome PDF Viewer
    ${prefs}    Create Dictionary    download.default_directory=${download directory}    plugins.plugins_disabled=${disabled}
    Call Method    ${chrome options}    add_experimental_option    prefs    ${prefs}
    Create Webdriver    Chrome    chrome_options=${chrome options}
    Goto    http://localhost/download.html
    Click Link    link    # downloads a file
    # wait for download to finish
    ${file}    Wait Until Keyword Succeeds    1 min    2 sec    Download should be done    ${download directory}

*** Keywords ***
Download should be done
    [Arguments]    ${directory}
    [Documentation]    Verifies that the directory has only one folder and it is not a temp file.
    ...
    ...    Returns path to the file
    ${files}    List Files In Directory    ${directory}
    Length Should Be    ${files}    1    Should be only one file in the download folder
    Should Not Match Regexp    ${files[0]}    (?i).*\\.tmp    Chrome is still downloading a file
    ${file}    Join Path    ${directory}    ${files[0]}
    Log    File was successfully downloaded to ${file}
    [Return]    ${file}

download.html 的内容：

 <html><body><a href="file.pdf" id="link">Click Here</a></body></html>

原文由 ombre42 发布，翻译遵循 CC BY-SA 3.0 许可协议

${home_dir} Get Environment Variable HOME ${download_dir} Join Path ${home_dir} Downloads ${result} Run Keyword And Return Status File Should Exist ${download_dir}/filename.pdf

机器人框架下载文件

你尚未登录，登录后可以

问一个鼠标滚动事件，这种是怎么实现的？

form对象根据表单dom元素的name属性获取元素对象是基于什么标准的？兼容性如何？

threejs用octree实现房间内第三人称漫游并且添加了碰撞，人物在碰撞到墙壁的时候不停的弹回，应该怎么修改才能不会疯狂的弹回？

Vue为什么说textarea标签不支持插值表达式的？

为什么下面的代码内部的 div 其 100% 高度可以跳过上层元素?

单页应用网站缓存不是由于index.html文件被缓存导致的吗？

election嵌套了一个web项目通信为什么会中断?

Stack Overflow 翻译