新手上路，请多包涵

关键点：

我已成功使用 VBA 执行以下操作：

使用 getElementsByName 登录网站
为将生成的报告选择参数（使用 getelementsby …）
选择参数后生成报告，将生成的数据集呈现到同一页面上的 iframe 中

重要提示 - 该网站是客户端

上面是简单的部分，困难的部分如下：

在将数据集导出到 csv 的 iframe 中单击 gif 图像

我尝试了以下方法：

 Dim idoc As HTMLDocument
Dim iframe As HTMLFrameElement
Dim iframe2 As HTMLDocument

Set idoc = objIE.document
Set iframe = idoc.all("iframename")
Set iframe2 = iframe.contentDocument

    Do Until InStr(1, objIE.document.all("iframename").contentDocument.innerHTML, "img.gif", vbTextCompare) = 0
        DoEvents
    Loop

为上面的逻辑提供一些上下文 -

我访问了主框架
我通过其名称元素访问了 iframe
我访问了 iframe 中的内容
我试图找到需要单击以导出到 csv 的 gif 图片

正是在这一行，它绊倒了说“对象不支持这个属性或方法”

还尝试通过 a 元素和 href 属性访问 iframe gif，但这完全失败了。我还尝试从其源 URL 抓取图像，但所有这些都将我带到了图像的来源页面。

注意：iframe 没有 ID，奇怪的是 gif 图像没有“onclick”元素/事件

最后考虑 - 尝试使用 R 抓取 iframe

访问 iframe 的 HTML 节点很简单，但是尝试访问 iframe 的属性以及随后的表节点被证明是不成功的。它返回的只是“Character(0)”

 library(rvest)
library(magrittr)

Blah <-read_html("web address redacted") %>%
  html_nodes("#iframe")%>%
  html_nodes("#img")%>%
  html_attr("#src")%>%
  #read_html()%>%
  head()
Blah

一旦 ai 包含 read_html，脚本就会返回以下错误：

if (grepl(“<|>”, x)) { 错误：参数长度为零

我怀疑这是指 Character(0)

感谢这里的任何指导！

非常感谢，

HTML

 <div align="center">
    <table id="table1" style="border-collapse: collapse" width="700" cellspacing="0" cellpadding="0" border="0">
        <tbody>
            <tr>
                <td colspan="6"> &nbsp;</td>
            </tr>
            <tr>
                <td colspan="6">
                    <a href="href redacted">
                        <img src="img.gif" width="38" height="38" border="0" align="right">
                    </a>
                    <strong>x - </strong>
                </td>
            </tr>
        </tbody>
    </table>
</div>

原文由 mojo3340 发布，翻译遵循 CC BY-SA 4.0 许可协议

html excel vba iframe web-scraping

阅读 1k

2 个回答

得票最新

社区维基

发布于
2022-12-22

✓ 已被采纳

有时使用 iframes 会很棘手。基于 html 你提供我已经创建了这个例子。哪个适用于本地，但它也适用于您吗？

要到达 IFrame 可以使用 frames 集合。希望您知道 name 的 IFrame ？

 Dim iframeDoc As MSHTML.HTMLDocument
Set iframeDoc = doc.frames("iframename").document

然后去 image 我们可以使用 querySelector 方法，例如：

 Dim img As MSHTML.HTMLImg
Set img = iframeDoc.querySelector("div table[id='table1'] tbody tr td a[href^='https://stackoverflow.com'] img")

选择器 a[href^='https://stackoverflow.com'] 选择 anchor 具有以给定文本开头的 href 属性。 ^ 表示开始。

然后，当我们有了图像时，只需简单地调用 click 在其父级上，这是所需的 anchor 。 HTH

完整示例：

 Option Explicit

' Add reference to Microsoft Internet Controls (SHDocVw)
' Add reference to Microsoft HTML Object Library

Sub Demo()

    Dim ie As SHDocVw.InternetExplorer
    Dim doc As MSHTML.HTMLDocument
    Dim url As String

    url = "file:///C:/Users/dusek/Documents/My Web Sites/mainpage.html"
    Set ie = New SHDocVw.InternetExplorer
    ie.Visible = True
    ie.navigate url

    While ie.Busy Or ie.readyState <> READYSTATE_COMPLETE
        DoEvents
    Wend

    Set doc = ie.document

    Dim iframeDoc As MSHTML.HTMLDocument
    Set iframeDoc = doc.frames("iframename").document
    If iframeDoc Is Nothing Then
        MsgBox "IFrame with name 'iframename' was not found."
        ie.Quit
        Exit Sub
    End If

    Dim img As MSHTML.HTMLImg
    Set img = iframeDoc.querySelector("div table[id='table1'] tbody tr td a[href^='https://stackoverflow.com'] img")
    If img Is Nothing Then
        MsgBox "Image element within iframe was not found."
        ie.Quit
        Exit Sub
    Else
        img.parentElement.Click
    End If

    ie.Quit
End Sub

使用的主页 HTML

 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">

<head>
<!-- saved from url=(0016)http://localhost -->
<meta content="text/html; charset=utf-8" http-equiv="Content-Type" />
<title>x -</title>
</head>

<body>
<iframe name="iframename" src="iframe1.html">
</iframe>
</body>

</html>

使用的 IFrame HTML（另存为文件 iframe1.html

 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">

<head>
<!-- saved from url=(0016)http://localhost -->
<meta content="text/html; charset=utf-8" http-equiv="Content-Type" />
<title>Untitled 2</title>
</head>

<body>
<div align="center">
    <table id="table1" style="border-collapse: collapse" width="700" cellspacing="0" cellpadding="0" border="0">
        <tbody>
            <tr>
                <td colspan="6"> &nbsp;</td>
            </tr>
            <tr>
                <td colspan="6">
                    <a href="https://stackoverflow.com/questions/44902558/accessing-object-in-iframe-using-vba">
                        <img src="img.gif" width="38" height="38" border="0" align="right">
                    </a>
                    <strong>x - </strong>
                </td>
            </tr>
        </tbody>
    </table>
</div>

</body>

</html>

顺便说一句，框架也可以通过它的索引引用 doc.frames(0).document 。感谢保罗布埃诺。

原文由 Daniel Dušek 发布，翻译遵循 CC BY-SA 4.0 许可协议

社区维基

发布于
2022-12-22

我想我会扩展已经给出的答案。

对于 Internet Explorer，您可能需要处理关于 iframe 的两种常见情况之一。

iframe 的 src 受同源策略限制：

iframe src 与着陆页有不同的来源，在这种情况下，由于同源策略，尝试访问它会导致 访问被拒绝。

解析度：

考虑使用 selenium basic 来自动化不同的浏览器，例如允许 CORS 的 Chrome/您可以切换到 iframe 并继续使用 iframe 文档

例子：

 Option Explicit
'download selenium https://github.com/florentbr/SeleniumBasic/releases/tag/v2.0.9.0
'Ensure latest applicable driver e.g. ChromeDriver.exe in Selenium folder
'VBE > Tools > References > Add reference to selenium type library
Public Sub Example()
    Dim d As WebDriver
    Const URL As String = "https://www.rosterresource.com/mlb-roster-grid/"
    Set d = New ChromeDriver
    With d
        .Start "Chrome"
        .get URL
        .SwitchToFrame .FindElementByCss("iframe") '< pass the iframe element as the identifier argument
        ' .SwitchToDefaultContent ''to go back to parent document.
        Stop '<== delete me later
        .Quit
    End With
End Sub

iframe 的 src 不受同源策略限制：

解析度：

已经给出的答案中详述的方法。此外，您可以提取要访问的 iframe 和 .Navigate2 的src

 .Navigate2 .document.querySelector("iframe").src

如果您只想使用 iframe 的内容，那么只需执行初始的 .Navigate2 iframe src 甚至不要访问初始登录页面

例子：

 Option Explicit
Public Sub NavigateUsingSrcOfIframe()
    Dim IE As New InternetExplorer
    With IE
        .Visible = True
        .Navigate2 "http://www.bursamalaysia.com/market/listed-companies/company-announcements/5978065"

        While .Busy Or .readyState < 4: DoEvents: Wend

        .Navigate2 .document.querySelector("iframe").src

        While .Busy Or .readyState < 4: DoEvents: Wend

        Stop '<== delete me later
        .Quit
    End With
End Sub

ShadowRoot 中的 iframe

不太可能的情况可能是 shadowroot 中的 iframe 。你真的应该有一个或另一个，而不是一个在另一个中。

解析度：

在这种情况下，您需要一个额外的访问器

Element.shadowRoot.querySelector("iframe").contentDocument

其中 Element 是您的父元素，附有 shadowRoot 。此方法仅在 shadowRoot mode 设置为 Open 时有效。

边注：

此处给出了一个很好的基于硒的示例，使用 ExecuteScript 返回 shadowRoot ： How Do I Access Elements in the Shadow DOM using Selenium in VBA?

原文由 QHarr 发布，翻译遵循 CC BY-SA 4.0 许可协议

撰写回答

你尚未登录，登录后可以

和开发者交流问题的细节
关注并接收问题和回答的更新提醒
参与内容的编辑和改进，让解决方法与时俱进

推荐问题

使用 VBA 访问 iframe 中的对象

你尚未登录，登录后可以

下面的代码可以使用vba来并发完成吗？

如何读出这个字典中的值？

js阻止冒泡问题？

Scss的rgba()方法无法对变量进行二次编译？

如何优化一下这段vba代码？

后端获取的html标签页面如何正常显示？

为何无法横向输出为pdf？

Stack Overflow 翻译